Как создавать игры в QSP

Что бы создать что то не очень сложное, не обязательно быть программистом. Попробую в этой статье объяснить основные моменты.
1) Вам понадобится конструктор. http://qsp.su
Это сайт разрабов, там есть все что надо.
Или я залил на файлообменник конструктор.
http://www.fayloobmennik.net/2728179

2) Создаете новую игру. Создаете стартовую локацию, она должна быть в самом верху. Пишите там код. Весь код записываете в верхнее правое окошко с названием "Выполнить при посещении." Создание локаций F7 или зеленый крестик в меню.

KILLALL
USEHTML=1
SHOWSTAT 1
SHOWOBJS 1
$ONGLOAD='loadg'
$ONGSAVE='saveg'
$ONNEWLOC  = 'LOCA'
$onobjsel = 'onobjsel'
showinput 0
$counter = 'counter'
$USERCOM='ОбработкаВвода'
debug=1

потом создаете локации
loadg
saveg
LOCA
onobjsel
counter
ОбработкаВвода

Вот вход в игру готов.
Создадим квартиру с двумя комнатами. Делаем две локации, назовем к примеру bedroom и sitroom

В стартовой локации пишем

act 'ИГРАТЬ':gt'bedroom'


!В локации bedroom пишем такой код.
'<center><B>Спальная</B></center>'
'Ваша спальная комната.'
act 'Идти в гостинную':gt'sitroom'

!В локации sitroom пишем такой код.
'<center><B>Гостинная</B></center>'
'Это гостинная комната, тут стоит диван, телевизор и стол.'
act 'Идти в спальную':gt'bedroom'

Вуаля. У вас есть игра с двумя комнатами между которыми можно перемещатся.

Если кому то будет интересно буду и дальше учить как из кирпичиков создать игру.

Если хотите что бы у вас отображалось и считалось время. То в локации комнат вставте такой код.
minut = minut + 1
clr
gs'stat'

Создайте новую локацию stat
и в нее вставте следующий код.

if minut >= 60:
:loopmin
set hour = hour + 1
set minut = minut - 60
     if minut >= 60:
     jump 'loopmin'
     end
end

if hour >= 24:
:loop
set day = day + 1
set week = week + 1
set hour = hour - 24
     if hour >= 24:
     jump 'loop'
     end
end

if minut < 10:set $nilmin = '0'
if minut >= 10:set $nilmin = ''
pl'Время <B><<hour>></B> часов <B><<$nilmin>><<minut>></B> минут'


Теперь у вас будет считатся и показыватся в окне дополнительного описания время. Стартовое время не заданно поэтому отсчет пойдет с 0 часов с 0 минут. Из подобных кирпичей можно собрать полноценную игру даже не задумываясь что делаешь.
Поймите, не надо сидеть вычесывать методы из головы, все уже есть. Берите кирпичи и сторойте, я подскажу. 

Характеристики ГГ. Это вещь очень тонкая и щекотливая. Нельзя просто вставить какой нибудь параметр просто так. Параметры должны быть связаны между собой. И они должны заставлять игрока удовлетворять потребности, а не сидеть на месте.
Например здоровье, сон и голод. Если сон равен нулю то будет падать здоровье, если голод равен нулю то опять же будет падать здоровье. Если здоровье дойдет до нуля то конец игры.
Сделать все это не сложно.

Перепишите этот код в локации stat
if hour >= 24:
:loop
set day = day + 1
set week = week + 1
set hour = hour - 24
     if hour >= 24:
     jump 'loop'
     end
end

следующим образом.
if hour >= 24:
:loop
set day = day + 1
set week = week + 1
set hour = hour - 24
son = son - 1
golod = golod - 1
     if hour >= 24:
     jump 'loop'
     end
end
if son <0:set health = health - 1&set son = 0
if golod <0:set health = health - 1&set golod = 0

if health <= 0:
gt'GAMEOVER'
exit
end

!И в конце добавте строчки
pl'Здоровье <<health>>'
pl'Сон <<son>>'
pl'Голод <<golod>>'

Создайте локацию GAMEOVER в которой в скобочках напишите 'Кибздец котенку, вы щелнули ластами и вашу тушку закопали.'

Но теперь если вы войдете в игры вы сразу же откините копыта. Поэтому в начальной локации добавим код health = 100

Что бы повысить сон создайте кровать в локации bedroom вставив этот код.
'В небольшой комнате стоит ваша двухспальная <a href="exec:GT ''bed''">кровать</a>.'

Создайте саму кровать. Это будет локация bed

Вставте туда этот код.
clr
gs'stat'
'Вы лежите на кровати.'
     if son > 10:
     'Спать почему то не хочется.'
     end
     if son <= 10:
         act 'Раздется и лечь спать':gt'bed2'
     end
     act 'Встать с кровати':gt'bedroom'

Создайте локацию bed2 и вставте туда этот код.
set health = health + 5
'Вы спите и вам ничего не снится.'
:loopson
set minut = minut + 1
set stime = stime + 1
if stime = 60:set stime = 0&set son = son + 3
clr
gs'stat'
if son > 23:
'Вы выспались'
     act 'Встать с кровати':gt'bedroom'
else
jump 'loopson'
end

С голодом все гораздо проще.
Вставте эту кнопку в локацию sitroom
     act 'Есть (15 мин)':
     cla
     set minut = minut + 15
          if golod >= 20:
          'Вы объелись и глядеть не можете на еду'
          end
          if golod < 20:
           set golod = golod + 20
           'Вы положили щей в тарелку и лихо их навернули.'
           end
     act 'Встать из за стола и вымыть посуду':gt'sitroom'
     end

Пожалуйста, голод и сон готовы.